From b43fb9ec552fc1a84599161478d77c6716dd9e0a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 13 Apr 2023 17:43:46 +0100
Subject: gentoo auto-resync : 13:04:2023 - 17:43:46

---
 app-emulation/free42/free42-3.0.19.ebuild | 46 +++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 app-emulation/free42/free42-3.0.19.ebuild

(limited to 'app-emulation/free42/free42-3.0.19.ebuild')

diff --git a/app-emulation/free42/free42-3.0.19.ebuild b/app-emulation/free42/free42-3.0.19.ebuild
new file mode 100644
index 000000000000..2a6f39b51817
--- /dev/null
+++ b/app-emulation/free42/free42-3.0.19.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+MY_PV="${PN}-nologo-${PV}"
+
+DESCRIPTION="An HP-42S Calculator Simulator"
+HOMEPAGE="https://thomasokken.com/free42/"
+SRC_URI="https://thomasokken.com/free42/upstream/${MY_PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+alsa"
+
+DEPEND="app-accessibility/at-spi2-core
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	alsa? ( media-libs/alsa-lib )"
+
+RDEPEND="${DEPEND}"
+
+DOCS=( CREDITS HISTORY README )
+S="${WORKDIR}/${MY_PV}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.14-fix-makefile.patch"
+	"${FILESDIR}/${PN}-3.0.16-fix-build-intel-lib.patch"
+)
+
+src_compile() {
+	local myconf
+	use alsa && myconf="AUDIO_ALSA=yes"
+	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" ${myconf} -C gtk
+	emake -C gtk clean
+	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" BCD_MATH=1 ${myconf} -C gtk
+}
+
+src_install() {
+	default
+	dobin gtk/free42bin gtk/free42dec
+}
-- 
cgit v1.2.3