From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 app-emulation/crun/crun-0.19.1-r1.ebuild | 70 ++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 app-emulation/crun/crun-0.19.1-r1.ebuild

(limited to 'app-emulation/crun/crun-0.19.1-r1.ebuild')

diff --git a/app-emulation/crun/crun-0.19.1-r1.ebuild b/app-emulation/crun/crun-0.19.1-r1.ebuild
new file mode 100644
index 000000000000..0590fee263af
--- /dev/null
+++ b/app-emulation/crun/crun-0.19.1-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="A fast and low-memory footprint OCI Container Runtime fully written in C"
+HOMEPAGE="https://github.com/containers/crun"
+SRC_URI="https://github.com/containers/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ppc64"
+IUSE="+bpf +caps criu +seccomp systemd static-libs"
+
+DEPEND="
+	sys-kernel/linux-headers
+	>=dev-libs/yajl-2.0.0
+	caps? ( sys-libs/libcap )
+	criu? ( >=sys-process/criu-3.15 )
+	seccomp? ( sys-libs/libseccomp )
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+# the crun test suite is comprehensive to the extent that tests will fail
+# within a sandbox environment, due to the nature of the privileges
+# required to create linux "containers".
+RESTRICT="test"
+
+DOCS=( README.md )
+
+PATCHES=( "${FILESDIR}/libcrun-linkage.patch" )
+
+src_prepare() {
+	default
+
+	# for libcrun-linkage.patch
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable bpf)
+		$(use_enable caps)
+		$(use_enable criu)
+		$(use_enable seccomp)
+		$(use_enable systemd)
+		$(usex static-libs '--enable-shared --enable-static' '--enable-shared --disable-static' '' '')
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake -C libocispec
+	emake crun
+}
+
+src_install() {
+	emake "DESTDIR=${D}" install-exec
+	doman crun.1
+	einstalldocs
+}
-- 
cgit v1.2.3