From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 app-emacs/pymacs/pymacs-0.26-r3.ebuild | 48 ++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 app-emacs/pymacs/pymacs-0.26-r3.ebuild

(limited to 'app-emacs/pymacs/pymacs-0.26-r3.ebuild')

diff --git a/app-emacs/pymacs/pymacs-0.26-r3.ebuild b/app-emacs/pymacs/pymacs-0.26-r3.ebuild
new file mode 100644
index 000000000000..d68770ec00be
--- /dev/null
+++ b/app-emacs/pymacs/pymacs-0.26-r3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+DISTUTILS_IN_SOURCE_BUILD=1
+
+inherit elisp distutils-r1
+
+DESCRIPTION="A tool that allows both-side communication beetween Python and Emacs Lisp"
+HOMEPAGE="https://www.emacswiki.org/emacs/PyMacs"
+SRC_URI="https://github.com/dgentry/${PN^}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 arm ~hppa ~ia64 ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc"
+
+BDEPEND="doc? (
+		>=dev-python/docutils-0.7
+		virtual/latex-base
+	)"
+
+S="${WORKDIR}/${P^}"
+
+SITEFILE="50${PN}-gentoo.el"
+
+# called by distutils-r1 for every python implementation
+python_configure() {
+	# pre-process the files but don't run distutils
+	emake PYSETUP=: PYTHON=${EPYTHON}
+}
+
+# called once
+python_compile_all() {
+	elisp_src_compile
+	if use doc; then
+		VARTEXFONTS="${T}"/fonts emake RST2LATEX=rst2latex.py pymacs.pdf
+	fi
+}
+
+python_install_all() {
+	elisp_src_install
+	distutils-r1_python_install_all
+	dodoc pymacs.rst
+	use doc && dodoc pymacs.pdf
+}
-- 
cgit v1.2.3