From cb6b2150348c9dc57c68bcba47bcdb6f20e8e508 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 22 Jun 2023 01:20:40 +0100
Subject: gentoo auto-resync : 22:06:2023 - 01:20:39

---
 .../haskell-mode-17.2_p20230616.ebuild             | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 app-emacs/haskell-mode/haskell-mode-17.2_p20230616.ebuild

(limited to 'app-emacs/haskell-mode/haskell-mode-17.2_p20230616.ebuild')

diff --git a/app-emacs/haskell-mode/haskell-mode-17.2_p20230616.ebuild b/app-emacs/haskell-mode/haskell-mode-17.2_p20230616.ebuild
new file mode 100644
index 000000000000..61922bc53618
--- /dev/null
+++ b/app-emacs/haskell-mode/haskell-mode-17.2_p20230616.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="Mode for editing (and running) Haskell programs in Emacs"
+HOMEPAGE="https://haskell.github.io/haskell-mode/
+	https://www.haskell.org/haskellwiki/Emacs#Haskell-mode"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/haskell/${PN}.git"
+else
+	[[ ${PV} == *_p20230616 ]] && COMMIT=41c0cf61591279a22ac511f925c041c40969bdb8
+	SRC_URI="https://github.com/haskell/${PN}/archive/${COMMIT}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-${COMMIT}
+	KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+fi
+
+LICENSE="GPL-3+ FDL-1.2+"
+SLOT="0"
+RESTRICT="test"  # Tests fail.
+
+BDEPEND="sys-apps/texinfo"
+
+DOCS=( NEWS README.md )
+ELISP_TEXINFO="doc/haskell-mode.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	# We install the logo in SITEETC, not in SITELISP
+	# https://github.com/haskell/haskell-mode/issues/102
+	sed -i -e "/defconst haskell-process-logo/{n;" \
+		-e "s:(.*\"\\(.*\\)\".*):\"${SITEETC}/${PN}/\\1\":}" \
+		haskell-process.el || die
+
+	eapply_user
+}
+
+src_compile() {
+	elisp_src_compile
+	elisp-make-autoload-file haskell-site-file.el
+}
+
+src_test() {
+	emake check-ert
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto "${SITEETC}"/${PN}
+	doins logo.svg
+}
-- 
cgit v1.2.3