From 1a39e197a344b8ec7e3ed6c173bdf2a1ccba5b6b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 28 Jun 2023 07:37:01 +0100
Subject: gentoo auto-resync : 28:06:2023 - 07:37:01

---
 app-emacs/embark/embark-9999.ebuild | 50 +++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 app-emacs/embark/embark-9999.ebuild

(limited to 'app-emacs/embark/embark-9999.ebuild')

diff --git a/app-emacs/embark/embark-9999.ebuild b/app-emacs/embark/embark-9999.ebuild
new file mode 100644
index 000000000000..38aa5db83044
--- /dev/null
+++ b/app-emacs/embark/embark-9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=27.1
+
+inherit elisp optfeature
+
+DESCRIPTION="Conveniently act on minibuffer completions inside GNU Emacs"
+HOMEPAGE="https://github.com/oantolin/embark/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/oantolin/${PN}.git"
+else
+	SRC_URI="https://github.com/oantolin/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND=">=app-emacs/compat-29.1.4.0"
+BDEPEND="${RDEPEND}"
+
+ELISP_REMOVE="avy-embark-collect.el embark-consult.el"
+
+DOCS=( README.org )
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	elisp_src_compile
+
+	elisp-make-autoload-file
+}
+
+src_install() {
+	elisp_src_install
+
+	doinfo ${PN}.texi
+}
+
+pkg_postinst() {
+	elisp_pkg_postinst
+
+	optfeature "Avy integration for Embark" app-emacs/avy-embark-collect
+	optfeature "Consult integration for Embark" app-emacs/embark-consult
+}
-- 
cgit v1.2.3