From 44a22ab89258383202cae3037c3a5685aa903251 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 5 Sep 2023 16:23:54 +0100
Subject: gentoo auto-resync : 05:09:2023 - 16:23:54

---
 app-emacs/eldev/eldev-1.6.ebuild | 50 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 app-emacs/eldev/eldev-1.6.ebuild

(limited to 'app-emacs/eldev/eldev-1.6.ebuild')

diff --git a/app-emacs/eldev/eldev-1.6.ebuild b/app-emacs/eldev/eldev-1.6.ebuild
new file mode 100644
index 000000000000..413e8c727a11
--- /dev/null
+++ b/app-emacs/eldev/eldev-1.6.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="Emacs Lisp Development Tool"
+HOMEPAGE="https://github.com/doublep/eldev/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/doublep/${PN}.git"
+else
+	SRC_URI="https://github.com/doublep/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+DOCS=( README.adoc )
+SITEFILE="50${PN}-gentoo.el"
+
+src_test() {
+	ELDEV_LOCAL="${S}" ./bin/${PN} test
+}
+
+src_install() {
+	elisp_src_install
+	dobin bin/${PN}
+
+	# NOTICE: If ELDEV_LOCAL is defined Eldev will use it
+	# to load up it's components,
+	# if it is not it will bootstrap itself from network
+	# always check if it uses installed Emacs Lisp files.
+	# Also, do not forget to run `env-update` & reopen your shell.
+	# https://github.com/doublep/eldev#influential-environment-variables
+	echo "ELDEV_LOCAL=${SITELISP}/${PN}" >> "${T}"/99${PN} || die
+	doenvd "${T}"/99${PN}
+}
+
+pkg_postinst() {
+	elisp_pkg_postinst
+
+	ewarn "Remember to run \`env-update && source /etc/profile\` if you plan"
+	ewarn "to use Eldev in a shell before logging out (or restarting"
+	ewarn "your login manager)."
+}
-- 
cgit v1.2.3