From db70871b2044b9bfde346d6f4027dafb0a013c4c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 15 Jun 2023 13:38:09 +0100
Subject: gentoo auto-resync : 15:06:2023 - 13:38:09

---
 app-emacs/dap-mode/dap-mode-0.7-r1.ebuild | 55 +++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 app-emacs/dap-mode/dap-mode-0.7-r1.ebuild

(limited to 'app-emacs/dap-mode/dap-mode-0.7-r1.ebuild')

diff --git a/app-emacs/dap-mode/dap-mode-0.7-r1.ebuild b/app-emacs/dap-mode/dap-mode-0.7-r1.ebuild
new file mode 100644
index 000000000000..e3e29dccd103
--- /dev/null
+++ b/app-emacs/dap-mode/dap-mode-0.7-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=26.1
+
+inherit elisp
+
+DESCRIPTION="Debug Adapter Protocol mode"
+HOMEPAGE="https://github.com/emacs-lsp/dap-mode/"
+SRC_URI="https://github.com/emacs-lsp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-emacs/bui
+	app-emacs/dash
+	app-emacs/f
+	app-emacs/ht
+	app-emacs/hydra
+	app-emacs/lsp-mode
+	app-emacs/lsp-treemacs
+	app-emacs/posframe
+	app-emacs/s
+"
+BDEPEND="
+	${RDEPEND}
+	test? ( app-emacs/ert-runner )
+"
+
+DOCS=( CHANGELOG.org README.org )
+PATCHES=( "${FILESDIR}"/${PN}-dap-ui-images-root-dir.patch )
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	sed "s|@SITEETC@|${SITEETC}/${PN}|" -i dap-ui.el || die
+}
+
+src_test() {
+	ert-runner -L . -L test --reporter ert+duration || die
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto ${SITEETC}/${PN}
+	doins -r icons
+}
-- 
cgit v1.2.3