From c8d60dada2ec8eb48b2d2b290cd6683ccec40e39 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 13 Feb 2021 21:41:11 +0000
Subject: gentoo (valentine's day) resync : 14.02.2021

---
 app-emacs/auctex/auctex-12.3.ebuild | 61 +++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 app-emacs/auctex/auctex-12.3.ebuild

(limited to 'app-emacs/auctex/auctex-12.3.ebuild')

diff --git a/app-emacs/auctex/auctex-12.3.ebuild b/app-emacs/auctex/auctex-12.3.ebuild
new file mode 100644
index 000000000000..809f35351cca
--- /dev/null
+++ b/app-emacs/auctex/auctex-12.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+NEED_EMACS=24
+
+inherit elisp
+
+DESCRIPTION="Extensible package for writing and formatting TeX files in Emacs"
+HOMEPAGE="https://www.gnu.org/software/auctex/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ FDL-1.3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+IUSE="preview-latex"
+
+RDEPEND="virtual/latex-base
+	preview-latex? (
+		app-text/dvipng
+		app-text/ghostscript-gpl
+	)"
+BDEPEND="${RDEPEND}"
+
+TEXMF="/usr/share/texmf-site"
+
+src_configure() {
+	econf \
+		--with-emacs \
+		--with-auto-dir="${EPREFIX}/var/lib/auctex" \
+		--with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
+		--with-packagelispdir="${EPREFIX}${SITELISP}/${PN}" \
+		--with-packagedatadir="${EPREFIX}${SITEETC}/${PN}" \
+		--with-texmf-dir="${EPREFIX}${TEXMF}" \
+		--disable-build-dir-test \
+		$(use_enable preview-latex preview)
+}
+
+src_compile() {
+	export VARTEXFONTS="${T}"/fonts
+	emake
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
+	if use preview-latex; then
+		elisp-site-file-install "${FILESDIR}/60${PN}-gentoo.el"
+	fi
+	dodoc ChangeLog* CHANGES FAQ INSTALL PROBLEMS.preview README RELEASE TODO
+}
+
+pkg_postinst() {
+	use preview-latex && texmf-update
+	elisp-site-regen
+}
+
+pkg_postrm() {
+	use preview-latex && texmf-update
+	elisp-site-regen
+}
-- 
cgit v1.2.3