From 34dea8e38f88007799629d0a56b12dec480b1d21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 20 Jun 2021 14:45:01 +0100
Subject: gentoo resync : 20.06.2021

---
 app-editors/ee/ee-1.5.2-r1.ebuild | 60 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 app-editors/ee/ee-1.5.2-r1.ebuild

(limited to 'app-editors/ee/ee-1.5.2-r1.ebuild')

diff --git a/app-editors/ee/ee-1.5.2-r1.ebuild b/app-editors/ee/ee-1.5.2-r1.ebuild
new file mode 100644
index 000000000000..3abbc7fc930c
--- /dev/null
+++ b/app-editors/ee/ee-1.5.2-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+DESCRIPTION="An easy to use text editor. A subset of aee"
+#HOMEPAGE="http://mahon.cwx.net/ http://www.users.uswest.net/~hmahon/"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://gentoo/${P}.src.tgz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~ia64 ~mips ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE=""
+
+RDEPEND="
+	!app-editors/ersatz-emacs
+	sys-libs/ncurses:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/easyedit-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-init-location.patch
+	"${FILESDIR}"/${PN}-signal.patch
+	"${FILESDIR}"/${PN}-Wformat-security.patch
+	"${FILESDIR}"/${PN}-gcc-10.patch
+)
+DOCS=( Changes README.${PN} ${PN}.i18n.guide ${PN}.msg )
+
+src_prepare() {
+	sed -i \
+		-e "s/make -/\$(MAKE) -/g" \
+		-e "/^buildee/s/$/ localmake/" \
+		Makefile
+
+	sed -i \
+		-e "s/\tcc /\t\\\\\$(CC) /" \
+		-e "/CFLAGS =/s/\" >/ \\\\\$(LDFLAGS)\" >/" \
+		-e "/other_cflag/s/ *-s//" \
+		-e "s/-lcurses/$($(tc-getPKG_CONFIG) --libs ncurses)/" \
+		create.make
+
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+	einstalldocs
+	keepdir /usr/share/${PN}
+}
-- 
cgit v1.2.3