From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 .../yubikey-manager-qt-0.5.1.ebuild                | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 app-crypt/yubikey-manager-qt/yubikey-manager-qt-0.5.1.ebuild

(limited to 'app-crypt/yubikey-manager-qt/yubikey-manager-qt-0.5.1.ebuild')

diff --git a/app-crypt/yubikey-manager-qt/yubikey-manager-qt-0.5.1.ebuild b/app-crypt/yubikey-manager-qt/yubikey-manager-qt-0.5.1.ebuild
new file mode 100644
index 000000000000..b9627b57544b
--- /dev/null
+++ b/app-crypt/yubikey-manager-qt/yubikey-manager-qt-0.5.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit eutils qmake-utils python-single-r1
+
+DESCRIPTION="Cross-platform application for configuring any YubiKey over all USB transports"
+HOMEPAGE="https://developers.yubico.com/yubikey-manager-qt https://github.com/Yubico/yubikey-manager-qt"
+# >yubikey-manager-qt-0.5.1 should have the tarball issue fixed: https://github.com/Yubico/yubikey-manager-qt/issues/49
+SRC_URI="https://github.com/Yubico/yubikey-manager-qt/releases/download/${P}/${P}.tar.gz -> ${P}.tar"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>=app-crypt/yubikey-manager-0.7.0[${PYTHON_USEDEP}]
+	<app-crypt/yubikey-manager-0.8
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/pyotherside[${PYTHON_USEDEP}]
+	dev-qt/qtsingleapplication[qt5(+),X]
+	dev-qt/qtdeclarative:5
+	dev-qt/qtsvg:5
+	dev-qt/qtquickcontrols:5[widgets]
+	dev-qt/qtwidgets:5"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	default
+
+	sed -i -e "s/ykman-cli//" ${PN}.pro || die
+	sed -e "/qtsingleapplication.pri/d" \
+		-e "/CONFIG += c++11/a CONFIG += qtsingleapplication" \
+		-i ykman-gui/ykman-gui.pro || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake install INSTALL_ROOT="${D}"
+
+	domenu resources/ykman-gui.desktop
+	doicon -s 128 resources/icons/ykman.png
+	doicon -s scalable resources/icons/ykman.svg
+
+	einstalldocs
+}
-- 
cgit v1.2.3