From 80208fb578cf92cc308906660ca6d7860c6b2a1f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 9 Mar 2018 16:53:27 +0000
Subject: gentoo resync : 09.03.2018

---
 app-crypt/xca/xca-1.4.1.ebuild | 58 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 app-crypt/xca/xca-1.4.1.ebuild

(limited to 'app-crypt/xca/xca-1.4.1.ebuild')

diff --git a/app-crypt/xca/xca-1.4.1.ebuild b/app-crypt/xca/xca-1.4.1.ebuild
new file mode 100644
index 000000000000..aaaacc6e8049
--- /dev/null
+++ b/app-crypt/xca/xca-1.4.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit xdg-utils
+
+DESCRIPTION="A GUI to OpenSSL, RSA public keys, certificates, signing requests etc"
+HOMEPAGE="http://hohnstaedt.de/xca/"
+SRC_URI="https://github.com/chris2511/${PN}/releases/download/RELEASE.${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="bindist doc libressl"
+
+RDEPEND="
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	!libressl? ( dev-libs/openssl:0=[bindist=] )
+	libressl? ( dev-libs/libressl:0= )
+	doc? ( app-text/linuxdoc-tools )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.0-desktop.patch"
+)
+
+src_configure() {
+	econf \
+		--with-qt-version=5 \
+		$(use_enable doc) \
+		STRIP=true
+}
+
+src_compile() {
+	# enforce all to avoid the automatic silent rules
+	emake all
+}
+
+src_install() {
+	# non standard destdir
+	emake install destdir="${ED}"
+	einstalldocs
+
+	insinto /etc/xca
+	doins misc/*.txt
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3