From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 app-crypt/xca/xca-1.3.2-r2.ebuild | 56 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 app-crypt/xca/xca-1.3.2-r2.ebuild

(limited to 'app-crypt/xca/xca-1.3.2-r2.ebuild')

diff --git a/app-crypt/xca/xca-1.3.2-r2.ebuild b/app-crypt/xca/xca-1.3.2-r2.ebuild
new file mode 100644
index 000000000000..c0ef3a8d4f8c
--- /dev/null
+++ b/app-crypt/xca/xca-1.3.2-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit flag-o-matic autotools
+
+DESCRIPTION="A GUI to OpenSSL, RSA public keys, certificates, signing requests etc"
+HOMEPAGE="http://xca.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="bindist doc libressl"
+
+RDEPEND="
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	!libressl? ( dev-libs/openssl:0=[bindist=] )
+	libressl? ( dev-libs/libressl:0= )
+	doc? ( app-text/linuxdoc-tools )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.0-desktop.patch"
+	"${FILESDIR}/${P}-build.patch"
+)
+
+src_prepare() {
+	default
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_configure() {
+	# bug #595440
+	append-cxxflags -std=c++11
+	econf \
+		--with-qt-version=5 \
+		$(use_enable doc) \
+		STRIP=true
+}
+
+src_compile() {
+	# enforce all to avoid the automatic silent rules
+	emake all
+}
+
+src_install() {
+	# non standard destdir
+	emake install destdir="${ED}"
+	einstalldocs
+
+	insinto /etc/xca
+	doins misc/*.txt
+}
-- 
cgit v1.2.3