From a9b37934d0877c4249ea35c9e9c5b8cf3b836c9e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 1 Aug 2022 09:15:09 +0100
Subject: gentoo auto-resync : 01:08:2022 - 09:15:08

---
 app-crypt/tc-play/tc-play-3.3.ebuild | 60 ++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 app-crypt/tc-play/tc-play-3.3.ebuild

(limited to 'app-crypt/tc-play/tc-play-3.3.ebuild')

diff --git a/app-crypt/tc-play/tc-play-3.3.ebuild b/app-crypt/tc-play/tc-play-3.3.ebuild
new file mode 100644
index 000000000000..bb69d8e37d7b
--- /dev/null
+++ b/app-crypt/tc-play/tc-play-3.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="A free, pretty much fully featured and stable TrueCrypt implementation"
+HOMEPAGE="https://github.com/bwalex/tc-play"
+SRC_URI="https://github.com/bwalex/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gnutls"
+
+DEPEND="
+	dev-libs/libgcrypt:=
+	dev-libs/libgpg-error
+	sys-apps/util-linux
+	sys-fs/lvm2
+	gnutls? ( net-libs/gnutls )
+	!gnutls? (
+		dev-libs/openssl:=
+	)
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.3-ldflags.patch
+)
+
+src_configure() {
+	local backend="openssl"
+	use gnutls && local backend="gcrypt"
+
+	EXTRA_MAKE_FLAGS=(
+		PBKDF_BACKEND="${backend}"
+		WARNFLAGS=""
+		CC="$(tc-getCC)"
+		AR="$(tc-getAR)"
+		PREFIX=/usr
+		LIBDIR=/usr/$(get_libdir)
+	)
+}
+
+src_compile() {
+	emake -f Makefile.classic \
+		tcplay \
+		"${EXTRA_MAKE_FLAGS[@]}"
+}
+
+src_install() {
+	emake -f Makefile.classic \
+		"${EXTRA_MAKE_FLAGS[@]}" \
+		install_program \
+		DESTDIR="${ED}"
+}
-- 
cgit v1.2.3