From af951a33bb81b1d784c3f4ea7bb7ca472e5b8d2b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 29 Jul 2023 10:39:26 +0100
Subject: gentoo auto-resync : 29:07:2023 - 10:39:26

---
 app-crypt/swtpm/swtpm-0.8.0-r2.ebuild | 66 +++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 app-crypt/swtpm/swtpm-0.8.0-r2.ebuild

(limited to 'app-crypt/swtpm/swtpm-0.8.0-r2.ebuild')

diff --git a/app-crypt/swtpm/swtpm-0.8.0-r2.ebuild b/app-crypt/swtpm/swtpm-0.8.0-r2.ebuild
new file mode 100644
index 000000000000..4f2d43053f44
--- /dev/null
+++ b/app-crypt/swtpm/swtpm-0.8.0-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="Libtpms-based TPM emulator"
+HOMEPAGE="https://github.com/stefanberger/swtpm"
+SRC_URI="https://github.com/stefanberger/swtpm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="fuse seccomp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="fuse? (
+		dev-libs/glib:2
+		sys-fs/fuse:0
+	)
+	seccomp? ( sys-libs/libseccomp )
+	dev-libs/libtasn1:=
+	acct-group/tss
+	acct-user/tss
+	dev-libs/openssl:0=
+	dev-libs/json-glib
+	dev-libs/libtpms"
+
+DEPEND="${RDEPEND}
+	test? (
+		net-misc/socat
+		dev-tcltk/expect
+	)"
+
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.6.0-fix-localca-path.patch"
+	"${FILESDIR}/${PN}-0.5.0-build-sys-Remove-WError.patch"
+	"${FILESDIR}/${PN}-0.7.2-Conditionalize-test-dependencies.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-openssl \
+		--without-selinux \
+		$(use_with fuse cuse) \
+		$(use_with seccomp) \
+		$(use_enable test)
+}
+
+src_install() {
+	default
+	fowners -R tss:root /var/lib/swtpm-localca
+	fperms 750 /var/lib/swtpm-localca
+	keepdir /var/lib/swtpm-localca
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3