From db70871b2044b9bfde346d6f4027dafb0a013c4c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 15 Jun 2023 13:38:09 +0100
Subject: gentoo auto-resync : 15:06:2023 - 13:38:09

---
 app-crypt/qca/Manifest            |   1 +
 app-crypt/qca/qca-2.3.6-r2.ebuild | 115 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 116 insertions(+)
 create mode 100644 app-crypt/qca/qca-2.3.6-r2.ebuild

(limited to 'app-crypt/qca')

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
index 1fc711b47292..ef4194a95893 100644
--- a/app-crypt/qca/Manifest
+++ b/app-crypt/qca/Manifest
@@ -4,4 +4,5 @@ DIST qca-2.3.5.tar.xz 741036 BLAKE2B 3948dc9b58a8ef03eec246cc14c7582d30e2513ea4b
 DIST qca-2.3.6.tar.xz 745864 BLAKE2B a3a5955215504b5703db304f241ae9c0c9b243c280cacb6180f631b3259b5f9a8af1c08b233f70e8e4130ac2e957dc3d8a99817b4dec2df0fab41b39bc54f8c8 SHA512 018bde919df28cfc9e5d6c5ad30724199a1a17437022751fb92bfc1ce691d8a56c62b661526e346f5a0c5ff7ffd556499f2ee25efe9f8b1698b3f8eee480811c
 EBUILD qca-2.3.5-r1.ebuild 1927 BLAKE2B 2c8deada2814ebe5c1f29d0ed5aa1331af687519d8acd4b901af41510ed846b104b512217516df272124435b6d14c6d9931fea1b77ed564fc4840aa0a7da3a31 SHA512 1f176e5a7d78c6c53a5e0ed7d20ad1647076f62d7dfa8e7691ead13a244308f5a8b1d6ae8baa97ca7296311e619589430ca95bb75b0a653e8890676c9e99b864
 EBUILD qca-2.3.6-r1.ebuild 1880 BLAKE2B cbcf607a8c064a1ae279ff35c461d5f300f8df8f6d72b5b90efd97572333dd1af9b6c812fd48cb7a0e9f0d599b68eaa34c10f414370a4685733ada81410a6503 SHA512 1416b00e7f1dba29ad54cd1e384652f2eef29a77e212e889dfc4ffa9adf9fbe8d8861f8a32a9ac3fbfeb7186d42f235f148b4e2c6cfccf460064703012033580
+EBUILD qca-2.3.6-r2.ebuild 2509 BLAKE2B f8c03aafb840507ea177eb734ecd9a46eec6186a4c8d4cbe3041558817cade3b626f5ec1ca6d1bd9fa89f6ef6f6385ebfee4ed4b99f41845377f32d725614354 SHA512 9c5ee6e25343bd529c3ab66312d5436db90020eee19e5d196f016fdb99b85504c43784fa7be54009f8e8cc30f31560d686423015e386d37ab3907da4e76be58f
 MISC metadata.xml 832 BLAKE2B 9044b545fa732c5f86c7dbb026630b4946a538ba77369eae28e894bf636ca60f6a31d7aad258fa19aee4c433d6d5a8e2a34a7c2850eef3a40d44261e592032b0 SHA512 b01bfe83343fdc265abc25922300cdc67f556a9a6f6db16918b0b3ee44c4e83db524695c5cb8952278f3e1f2e5d60a49bcc9312b35ab95f0ecc42e03764fb6bd
diff --git a/app-crypt/qca/qca-2.3.6-r2.ebuild b/app-crypt/qca/qca-2.3.6-r2.ebuild
new file mode 100644
index 000000000000..0cdc05cdc7ad
--- /dev/null
+++ b/app-crypt/qca/qca-2.3.6-r2.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake kde.org multibuild qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="https://userbase.kde.org/QCA"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="botan debug doc examples gcrypt gpg logger nss pkcs11 +qt5 qt6 sasl softstore +ssl test"
+REQUIRED_USE="|| ( qt5 qt6 )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	botan? ( dev-libs/botan:3= )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	pkcs11? (
+		>=dev-libs/openssl-1.1
+		dev-libs/pkcs11-helper
+	)
+	qt5? ( >=dev-qt/qtcore-5.14:5 )
+	qt6? (
+		dev-qt/qtbase:6
+		dev-qt/qt5compat:6
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? ( >=dev-libs/openssl-1.1:= )
+"
+DEPEND="${RDEPEND}
+	test? (
+		qt5? (
+			dev-qt/qtnetwork:5
+			dev-qt/qttest:5
+		)
+		qt6? ( dev-qt/qtbase:6[network,test] )
+	)
+"
+BDEPEND="
+	doc? (
+		app-doc/doxygen[dot]
+		virtual/latex-base
+	)
+"
+
+PATCHES=( "${FILESDIR}/${PN}-disable-pgp-test.patch" )
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_mkspecsdir)/features"
+			-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_plugindir)"
+			$(qca_plugin_use botan)
+			$(qca_plugin_use gcrypt)
+			$(qca_plugin_use gpg gnupg)
+			$(qca_plugin_use logger)
+			$(qca_plugin_use nss)
+			$(qca_plugin_use pkcs11)
+			$(qca_plugin_use sasl cyrus-sasl)
+			$(qca_plugin_use softstore)
+			$(qca_plugin_use ssl ossl)
+			-DBUILD_TESTS=$(usex test)
+		)
+		if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
+				mycmakeargs+=( -DBUILD_WITH_QT6=ON )
+		else
+				mycmakeargs+=( -DBUILD_WITH_QT6=OFF )
+		fi
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_test() {
+	mytest() {
+		local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+		cmake_src_test
+	}
+	multibuild_foreach_variant mytest
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null || die
+		doxygen Doxyfile || die
+		dodoc -r apidocs/html
+		popd >/dev/null || die
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}
-- 
cgit v1.2.3