From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 app-crypt/pesign/pesign-114.ebuild | 58 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 app-crypt/pesign/pesign-114.ebuild

(limited to 'app-crypt/pesign/pesign-114.ebuild')

diff --git a/app-crypt/pesign/pesign-114.ebuild b/app-crypt/pesign/pesign-114.ebuild
new file mode 100644
index 000000000000..bd65febf96c3
--- /dev/null
+++ b/app-crypt/pesign/pesign-114.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Tools for manipulating signed PE-COFF binaries"
+HOMEPAGE="https://github.com/rhboot/pesign"
+SRC_URI="https://github.com/rhboot/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/openssl:=
+	dev-libs/popt
+	sys-apps/util-linux
+	>=sys-libs/efivar-38
+"
+DEPEND="${RDEPEND}
+	sys-boot/gnu-efi
+"
+BDEPEND="
+	sys-apps/help2man
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-114-wanalyzer-diagnostic.patch
+	"${FILESDIR}"/${PN}-114-no-werror.patch
+
+	"${FILESDIR}"/${P}-format-string.patch
+)
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR)" \
+		ARFLAGS="-cvqs" \
+		AS="$(tc-getAS)" \
+		CC="$(tc-getCC)" \
+		LD="$(tc-getLD)" \
+		OBJCOPY="$(tc-getOBJCOPY)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		RANLIB="$(tc-getRANLIB)" \
+		rundir="${EPREFIX}/var/run"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" VERSION="${PVR}" rundir="${EPREFIX}/var/run" install
+	einstalldocs
+
+	# remove some files that don't make sense for Gentoo installs
+	rm -rf "${ED}/etc" "${ED}/var" "${ED}/usr/share/doc/${PF}/COPYING" || die
+}
-- 
cgit v1.2.3