From 8c364c784966be1700ea39ae45028f3e9be9cae0 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 27 Mar 2018 22:40:05 +0100
Subject: gentoo resync : 27.03.2018

---
 app-crypt/acme-tiny/acme-tiny-4.0.3.ebuild | 48 ++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 app-crypt/acme-tiny/acme-tiny-4.0.3.ebuild

(limited to 'app-crypt/acme-tiny/acme-tiny-4.0.3.ebuild')

diff --git a/app-crypt/acme-tiny/acme-tiny-4.0.3.ebuild b/app-crypt/acme-tiny/acme-tiny-4.0.3.ebuild
new file mode 100644
index 000000000000..b9815c348094
--- /dev/null
+++ b/app-crypt/acme-tiny/acme-tiny-4.0.3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+inherit distutils-r1 eapi7-ver
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/diafygi/${PN}.git"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/diafygi/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A tiny, auditable script for Let's Encrypt's ACME Protocol"
+HOMEPAGE="https://github.com/diafygi/acme-tiny"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+RDEPEND="dev-libs/openssl:0"
+
+pkg_setup() {
+	if [[ ${PV} != 9999 ]]; then
+		export SETUPTOOLS_SCM_PRETEND_VERSION="${PV}"
+	fi
+}
+
+src_prepare() {
+	sed -i 's|#!/usr/bin/sh|#!/bin/sh|g' README.md || die
+
+	distutils-r1_src_prepare
+}
+
+pkg_postinst() {
+	for v in ${REPLACING_VERSIONS}; do
+		if ver_test "$v" "-lt" "4.0.3" || ver_test "$v" "-ge" "9999"; then
+			einfo "The --account-email flag has been changed to --contact and"
+			einfo "has different syntax."
+			einfo "Please update your scripts accordingly"
+		fi
+	done
+}
-- 
cgit v1.2.3