From e33383d972aad8129fd4c1ee2b87f529f6efa8e9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 24 Nov 2022 01:09:44 +0000
Subject: gentoo auto-resync : 24:11:2022 - 01:09:44

---
 app-crypt/acme-sh/acme-sh-3.0.5.ebuild | 54 ++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 app-crypt/acme-sh/acme-sh-3.0.5.ebuild

(limited to 'app-crypt/acme-sh/acme-sh-3.0.5.ebuild')

diff --git a/app-crypt/acme-sh/acme-sh-3.0.5.ebuild b/app-crypt/acme-sh/acme-sh-3.0.5.ebuild
new file mode 100644
index 000000000000..c83e0e967104
--- /dev/null
+++ b/app-crypt/acme-sh/acme-sh-3.0.5.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN/-/.}"
+MY_P="${MY_PN}-${PV}"
+
+inherit optfeature
+
+DESCRIPTION="A pure Unix shell script implementing ACME client protocol"
+HOMEPAGE="https://github.com/acmesh-official/acme.sh"
+SRC_URI="https://github.com/acmesh-official/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+IUSE="selinux"
+
+RDEPEND="
+	dev-libs/openssl:0
+	net-misc/curl
+	net-misc/socat
+	selinux? ( sec-policy/selinux-certbot )
+"
+
+src_install() {
+	newdoc deploy/README.md README-deploy.md
+	newdoc dnsapi/README.md README-dnsapi.md
+	rm {deploy,dnsapi}/README.md || die
+	einstalldocs
+
+	exeinto /usr/share/acme.sh
+	doexe acme.sh
+
+	insinto /usr/share/acme.sh
+	doins -r deploy dnsapi notify
+
+	keepdir /etc/acme-sh
+	doenvd "${FILESDIR}"/99acme-sh
+
+	insinto /etc/bash/bashrc.d
+	doins "${FILESDIR}"/acme.sh
+
+	dosym ../share/acme.sh/acme.sh usr/bin/acme.sh
+}
+
+pkg_postinst() {
+	optfeature_header "For webserver mode, install a supported web server:"
+	optfeature "using apache2 webserver mode" www-servers/apache
+	optfeature "using nginx webserver mode" www-servers/nginx
+}
-- 
cgit v1.2.3