From 40aaaa64e86ba6710bbeb31c4615a6ce80e75e11 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 28 Apr 2021 20:21:43 +0100
Subject: gentoo resync : 28.04.2021

---
 app-cdr/gcdemu/gcdemu-3.2.5.ebuild | 56 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 app-cdr/gcdemu/gcdemu-3.2.5.ebuild

(limited to 'app-cdr/gcdemu/gcdemu-3.2.5.ebuild')

diff --git a/app-cdr/gcdemu/gcdemu-3.2.5.ebuild b/app-cdr/gcdemu/gcdemu-3.2.5.ebuild
new file mode 100644
index 000000000000..d6e7b2808caa
--- /dev/null
+++ b/app-cdr/gcdemu/gcdemu-3.2.5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit cmake gnome2-utils python-single-r1 xdg-utils
+
+DESCRIPTION="Gtk+ GUI for controlling cdemu-daemon"
+HOMEPAGE="https://cdemu.sourceforge.io"
+SRC_URI="https://download.sourceforge.net/cdemu/gcdemu/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# librsvg for pixbuf-loader
+RDEPEND="${PYTHON_DEPS}
+	app-cdr/cdemu-daemon:0/7
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+	')
+	gnome-base/librsvg:2
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]"
+BDEPEND="${PYTHON_DEPS}
+	dev-util/desktop-file-utils
+	>=dev-util/intltool-0.21
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS README )
+
+src_prepare() {
+	cmake_src_prepare
+	python_fix_shebang src/gcdemu
+}
+
+src_configure() {
+	local mycmakeargs=( -DPOST_INSTALL_HOOKS=OFF )
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3