From 4d3b8f8b38eda2e6cfa39c2efcf4f9c4055c2d7d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 12 Jan 2023 17:46:56 +0000
Subject: gentoo auto-resync : 12:01:2023 - 17:46:56

---
 app-benchmarks/siege/siege-4.1.6.ebuild | 51 +++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 app-benchmarks/siege/siege-4.1.6.ebuild

(limited to 'app-benchmarks/siege/siege-4.1.6.ebuild')

diff --git a/app-benchmarks/siege/siege-4.1.6.ebuild b/app-benchmarks/siege/siege-4.1.6.ebuild
new file mode 100644
index 000000000000..eff06d8f8eec
--- /dev/null
+++ b/app-benchmarks/siege/siege-4.1.6.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools bash-completion-r1
+
+DESCRIPTION="A HTTP regression testing and benchmarking utility"
+HOMEPAGE="https://www.joedog.org/siege-home https://github.com/JoeDog/siege"
+SRC_URI="http://download.joedog.org/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~x86 ~x64-macos"
+SLOT="0"
+IUSE="ssl"
+
+RDEPEND="
+	sys-libs/zlib
+	ssl? ( dev-libs/openssl:0= )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	# bundled macros break recent libtool
+	# remove /usr/lib from LDFLAGS, bug #732886
+	sed -i \
+		-e '/AC_PROG_SHELL/d' \
+		-e 's/SSL_LDFLAGS="-L.*lib"/SSL_LDFLAGS=""/g' \
+		-e 's/Z_LDFLAGS="-L.*lib"/Z_LDFLAGS=""/g' \
+		configure.ac || die "Failed to sed configure.ac"
+	rm *.m4 || die "failed to remove bundled macros"
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=( $(use_with ssl ssl "${EPREFIX}/usr") )
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+	dodoc AUTHORS ChangeLog INSTALL README* doc/siegerc doc/urls.txt
+
+	newbashcomp "${FILESDIR}/${PN}".bash-completion "${PN}"
+}
+
+pkg_postinst() {
+	elog "An example ~/.siegerc file has been installed in"
+	elog "${EPREFIX}/usr/share/doc/${PF}/"
+}
-- 
cgit v1.2.3