From 0d7aefa5885e7552b4c2221df9f54e5930696228 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 10 Jul 2022 13:27:24 +0100
Subject: gentoo auto-resync : 10:07:2022 - 13:27:24

---
 app-arch/zpaq/zpaq-7.15-r1.ebuild | 47 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 app-arch/zpaq/zpaq-7.15-r1.ebuild

(limited to 'app-arch/zpaq/zpaq-7.15-r1.ebuild')

diff --git a/app-arch/zpaq/zpaq-7.15-r1.ebuild b/app-arch/zpaq/zpaq-7.15-r1.ebuild
new file mode 100644
index 000000000000..cd79e48be432
--- /dev/null
+++ b/app-arch/zpaq/zpaq-7.15-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic pax-utils toolchain-funcs
+
+MY_P="${PN}${PV/./}"
+
+DESCRIPTION="Journaling incremental deduplicating archiving compressor"
+HOMEPAGE="http://mattmahoney.net/dc/zpaq.html"
+SRC_URI="http://mattmahoney.net/dc/${MY_P}.zip"
+S="${WORKDIR}"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug +jit"
+
+# perl for pod2man
+BDEPEND="
+	app-arch/unzip
+	dev-lang/perl"
+
+src_compile() {
+	use debug || append-cppflags -DNDEBUG
+	use jit || append-cppflags -DNOJIT
+	emake CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS}"
+}
+
+src_test() {
+	use jit && pax-mark m zpaq
+	default
+}
+
+src_install() {
+	emake install PREFIX="${ED}"/usr
+	use jit && pax-mark m "${ED}"/usr/bin/zpaq
+	einstalldocs
+}
+
+pkg_postinst() {
+	if ! has_version app-arch/zpaq-extras; then
+		elog "You may also want to install app-arch/zpaq-extras package which provides"
+		elog "few additional configs and preprocessors for use with zpaq."
+	fi
+}
-- 
cgit v1.2.3