From 4e777c0133d093c9c8b992c92e0f244e2055bf71 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 5 May 2023 05:29:57 +0100
Subject: gentoo auto-resync : 05:05:2023 - 05:29:57

---
 app-arch/cpio/cpio-2.14.ebuild | 50 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 app-arch/cpio/cpio-2.14.ebuild

(limited to 'app-arch/cpio/cpio-2.14.ebuild')

diff --git a/app-arch/cpio/cpio-2.14.ebuild b/app-arch/cpio/cpio-2.14.ebuild
new file mode 100644
index 000000000000..1d3937b4bbab
--- /dev/null
+++ b/app-arch/cpio/cpio-2.14.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A file archival tool which can also read and write tar files"
+HOMEPAGE="https://www.gnu.org/software/cpio/cpio.html"
+SRC_URI="mirror://gnu/cpio/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="nls"
+
+PDEPEND="
+	app-alternatives/cpio
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.12-non-gnu-compilers.patch #275295
+	"${FILESDIR}"/${PN}-2.14-sysmacros-glibc-2.26.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable nls)
+		--bindir="${EPREFIX}"/bin
+		--with-rmt="${EPREFIX}"/usr/sbin/rmt
+		# install as gcpio for better compatibility with non-GNU userland
+		--program-prefix=g
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+pkg_postinst() {
+	# ensure to preserve the symlink before app-alternatives/cpio
+	# is installed
+	if [[ ! -h ${EROOT}/bin/cpio ]]; then
+		ln -s gcpio "${EROOT}/bin/cpio" || die
+	fi
+}
-- 
cgit v1.2.3