From d1d8adbfd346340c3784c72a9fa0868dde6ff736 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 27 Jul 2022 15:01:59 +0100
Subject: gentoo auto-resync : 27:07:2022 - 15:01:59

---
 app-admin/xstow/xstow-1.1.0.ebuild | 53 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 app-admin/xstow/xstow-1.1.0.ebuild

(limited to 'app-admin/xstow/xstow-1.1.0.ebuild')

diff --git a/app-admin/xstow/xstow-1.1.0.ebuild b/app-admin/xstow/xstow-1.1.0.ebuild
new file mode 100644
index 000000000000..5a06f7a62ad8
--- /dev/null
+++ b/app-admin/xstow/xstow-1.1.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Replacement for GNU stow with extensions"
+HOMEPAGE="http://xstow.sourceforge.net/"
+SRC_URI="mirror://sourceforge/xstow/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="ncurses"
+
+DEPEND="ncurses? ( sys-libs/ncurses:= )"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-clang.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with ncurses curses)
+}
+
+src_install() {
+	emake DESTDIR="${D}" docdir="${EPREFIX}/usr/share/doc/${PF}/html" install
+	dodoc AUTHORS ChangeLog NEWS README TODO
+
+	# Create new STOWDIR
+	keepdir /var/lib/xstow
+
+	# Install env.d file to add STOWDIR to PATH and LDPATH
+	doenvd "${FILESDIR}"/99xstow
+}
+
+pkg_postinst() {
+	elog "We now recommend that you use /var/lib/xstow as your STOWDIR"
+	elog "instead of /usr/local in order to avoid conflicts with the"
+	elog "symlink from /usr/lib64 -> /usr/lib.  See Bug 246264"
+	elog "(regarding app-admin/stow, equally applicable to XStow) for"
+	elog "more details on this change."
+	elog "For your convenience, PATH has been updated to include"
+	elog "/var/lib/bin."
+}
-- 
cgit v1.2.3