From f4fc10428424904caf2035cffc442195cb088b2c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 28 Jul 2021 10:27:13 +0100
Subject: gentoo resync : 28.07.2021

---
 .../prelude-manager-5.1.0-r1.ebuild                | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 app-admin/prelude-manager/prelude-manager-5.1.0-r1.ebuild

(limited to 'app-admin/prelude-manager/prelude-manager-5.1.0-r1.ebuild')

diff --git a/app-admin/prelude-manager/prelude-manager-5.1.0-r1.ebuild b/app-admin/prelude-manager/prelude-manager-5.1.0-r1.ebuild
new file mode 100644
index 000000000000..1fcb2078c9d1
--- /dev/null
+++ b/app-admin/prelude-manager/prelude-manager-5.1.0-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd tmpfiles
+
+DESCRIPTION="Bus communication for all Prelude modules"
+HOMEPAGE="https://www.prelude-siem.org"
+SRC_URI="https://www.prelude-siem.org/pkg/src/5.1.0/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbx geoip tcpd xml"
+
+RDEPEND="net-libs/gnutls:=
+	>=dev-libs/libprelude-5.1.0
+	<dev-libs/libprelude-6
+	dbx? (
+		>=dev-libs/libpreludedb-5.1.0
+		<dev-libs/libpreludedb-6
+	)
+	geoip? ( dev-libs/libmaxminddb )
+	tcpd? ( sys-apps/tcp-wrappers )
+	xml? ( dev-libs/libxml2 )"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.1.0-run.patch"
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--localstatedir="${EPREFIX}/var"
+		$(use_with dbx libpreludedb-prefix)
+		$(use_enable geoip libmaxminddb)
+		$(use_with tcpd libwrap)
+		$(usex xml '' '--without-xml-prefix')
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	rm -rv "${ED}/run" || die "rm failed"
+	keepdir /var/spool/prelude-manager{,/failover,/scheduler}
+
+	find "${D}" -name '*.la' -delete || die
+
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	newtmpfiles "${FILESDIR}/${PN}.run" "${PN}.conf"
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+}
-- 
cgit v1.2.3