From 590b9b7b03bf4651e099949e318755af7cfa81b8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 1 Aug 2021 22:03:23 +0100
Subject: gentoo resync : 01.08.2021

---
 app-admin/pass/pass-1.7.4.ebuild | 79 ----------------------------------------
 1 file changed, 79 deletions(-)
 delete mode 100644 app-admin/pass/pass-1.7.4.ebuild

(limited to 'app-admin/pass/pass-1.7.4.ebuild')

diff --git a/app-admin/pass/pass-1.7.4.ebuild b/app-admin/pass/pass-1.7.4.ebuild
deleted file mode 100644
index d1349cc29760..000000000000
--- a/app-admin/pass/pass-1.7.4.ebuild
+++ /dev/null
@@ -1,79 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit bash-completion-r1 elisp-common
-
-DESCRIPTION="Stores, retrieves, generates, and synchronizes passwords securely"
-HOMEPAGE="https://www.passwordstore.org/"
-SRC_URI="https://git.zx2c4.com/password-store/snapshot/password-store-${PV}.tar.xz"
-
-SLOT="0"
-LICENSE="GPL-2"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~x64-macos"
-IUSE="+git wayland X zsh-completion fish-completion emacs dmenu importers elibc_Darwin"
-
-RDEPEND="
-	app-crypt/gnupg
-	media-gfx/qrencode
-	>=app-text/tree-1.7.0
-	git? ( dev-vcs/git )
-	wayland? ( gui-apps/wl-clipboard )
-	X? ( x11-misc/xclip )
-	elibc_Darwin? ( app-misc/getopt )
-	zsh-completion? ( app-shells/gentoo-zsh-completions )
-	fish-completion? ( app-shells/fish )
-	dmenu? ( x11-misc/dmenu x11-misc/xdotool )
-	emacs? ( >=app-editors/emacs-23.1:* >=app-emacs/f-0.11.0 >=app-emacs/s-1.9.0 >=app-emacs/with-editor-2.5.11 )
-"
-
-S="${WORKDIR}/password-store-${PV}"
-
-src_prepare() {
-	default
-
-	use elibc_Darwin || return
-	# use coreutils'
-	sed -i -e 's/openssl base64/base64/g' src/platform/darwin.sh || die
-	# host getopt isn't cool, and we aren't brew (rip out brew reference)
-	sed -i -e '/^GETOPT=/s/=.*$/=getopt-long/' src/platform/darwin.sh || die
-	# make sure we can find "mount"
-	sed -i -e 's:mount -t:/sbin/mount -t:' src/platform/darwin.sh || die
-}
-
-src_compile() {
-	use emacs && elisp-compile contrib/emacs/*.el
-}
-
-src_install() {
-	emake install \
-		DESTDIR="${D}" \
-		PREFIX="${EPREFIX}/usr" \
-		BASHCOMPDIR="$(get_bashcompdir)" \
-		WITH_BASHCOMP=yes \
-		WITH_ZSHCOMP=$(usex zsh-completion) \
-		WITH_FISHCOMP=$(usex fish-completion)
-	use dmenu && dobin contrib/dmenu/passmenu
-	if use emacs; then
-		elisp-install ${PN} contrib/emacs/*.{el,elc}
-		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
-	fi
-	if use importers; then
-		exeinto /usr/share/${PN}/importers
-		doexe contrib/importers/*
-	fi
-}
-
-pkg_postinst() {
-	use emacs && elisp-site-regen
-	if use importers; then
-		einfo "To import passwords from other password managers, you may use the"
-		einfo "various importer scripts found in:"
-		einfo "    ${EROOT}/usr/share/${PN}/importers/"
-	fi
-}
-
-pkg_postrm() {
-	use emacs && elisp-site-regen
-}
-- 
cgit v1.2.3