From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 app-admin/monit/monit-5.29.0.ebuild | 60 +++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 app-admin/monit/monit-5.29.0.ebuild

(limited to 'app-admin/monit/monit-5.29.0.ebuild')

diff --git a/app-admin/monit/monit-5.29.0.ebuild b/app-admin/monit/monit-5.29.0.ebuild
new file mode 100644
index 000000000000..5baeadcf536d
--- /dev/null
+++ b/app-admin/monit/monit-5.29.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 pam systemd
+
+DESCRIPTION="Monitoring and managing daemons or similar programs running on a Unix system"
+HOMEPAGE="http://mmonit.com/monit/"
+SRC_URI="http://mmonit.com/monit/dist/${P}.tar.gz"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE="ipv6 pam ssl"
+
+RDEPEND="sys-libs/zlib:=
+	virtual/libcrypt:=
+	pam? ( sys-libs/pam )
+	ssl? ( dev-libs/openssl:0= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+src_prepare() {
+	default
+	sed -i -e '/^INSTALL_PROG/s/-s//' Makefile.in || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with ipv6)
+		$(use_with pam)
+		$(use_with ssl)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/monit.logrotate monit
+
+	insinto /etc; insopts -m600; doins monitrc
+	newinitd "${FILESDIR}"/monit.initd-5.0-r1 monit
+	systemd_dounit system/startup/${PN}.service
+
+	use pam && newpamd "${FILESDIR}"/${PN}.pamd ${PN}
+
+	dobashcomp system/bash/monit
+}
+
+pkg_postinst() {
+	elog "Sample configurations are available at:"
+	elog "http://mmonit.com/monit/documentation/"
+}
-- 
cgit v1.2.3