From e68d405c5d712af4387159df07e226217bdda049 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 6 Apr 2022 22:33:41 +0100
Subject: gentoo resync : 06.04.2022

---
 app-admin/metalog/metalog-20220214.ebuild | 66 +++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 app-admin/metalog/metalog-20220214.ebuild

(limited to 'app-admin/metalog/metalog-20220214.ebuild')

diff --git a/app-admin/metalog/metalog-20220214.ebuild b/app-admin/metalog/metalog-20220214.ebuild
new file mode 100644
index 000000000000..a774d0a007e2
--- /dev/null
+++ b/app-admin/metalog/metalog-20220214.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="A highly configurable replacement for syslogd/klogd"
+HOMEPAGE="https://github.com/hvisage/metalog"
+SRC_URI="https://github.com/hvisage/${PN}/archive/${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin"
+IUSE="unicode"
+
+RDEPEND="dev-libs/libpcre2"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/autoconf-archive
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9-metalog-conf.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with unicode)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README NEWS metalog.conf
+
+	into /
+	newsbin "${FILESDIR}"/consolelog.sh-r1 consolelog.sh
+
+	newinitd "${FILESDIR}"/metalog.initd-r1 metalog
+	newconfd "${FILESDIR}"/metalog.confd metalog
+	systemd_newunit "${FILESDIR}"/${PN}.service-r1 ${PN}.service
+}
+
+pkg_preinst() {
+	if [[ -d "${ROOT}"/etc/metalog && ! -e "${ROOT}"/etc/metalog.conf ]] ; then
+		mv -f "${ROOT}"/etc/metalog/metalog.conf "${ROOT}"/etc/metalog.conf
+		rmdir "${ROOT}"/etc/metalog
+		export MOVED_METALOG_CONF=true
+	else
+		export MOVED_METALOG_CONF=false
+	fi
+}
+
+pkg_postinst() {
+	if ${MOVED_METALOG_CONF} ; then
+		ewarn "The default metalog.conf file has been moved"
+		ewarn "from ${EROOT}/etc/metalog/metalog.conf to just"
+		ewarn "${EROOT}/etc/metalog.conf.  If you had a standard"
+		ewarn "setup, the file has been moved for you."
+	fi
+}
-- 
cgit v1.2.3