From 0f3400581b3370a12b1581c6394b74327181f3e8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 4 Apr 2023 17:23:10 +0100
Subject: gentoo auto-resync : 04:04:2023 - 17:23:09

---
 app-admin/mcelog/mcelog-193.ebuild | 51 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 app-admin/mcelog/mcelog-193.ebuild

(limited to 'app-admin/mcelog/mcelog-193.ebuild')

diff --git a/app-admin/mcelog/mcelog-193.ebuild b/app-admin/mcelog/mcelog-193.ebuild
new file mode 100644
index 000000000000..7d504ed20d59
--- /dev/null
+++ b/app-admin/mcelog/mcelog-193.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit linux-info python-any-r1 systemd toolchain-funcs
+
+DESCRIPTION="A tool to log and decode Machine Check Exceptions"
+HOMEPAGE="http://mcelog.org/"
+SRC_URI="https://github.com/andikleen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-mcelog )"
+DEPEND="${PYTHON_DEPS}"
+
+# TODO: add mce-inject to the tree to support test phase
+RESTRICT="test"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		local CONFIG_CHECK="~X86_MCE"
+		kernel_is -ge 4 12 && CONFIG_CHECK+=" ~X86_MCELOG_LEGACY"
+		check_extra_config
+	fi
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.8_pre1-timestamp-${PN}.patch \
+		"${FILESDIR}"/${PN}-129-debugflags.patch
+	eapply_user
+	tc-export CC
+	python_fix_shebang genconfig.py
+}
+
+src_install() {
+	default
+
+	insinto /etc/logrotate.d/
+	newins ${PN}.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}.init-r1 ${PN}
+	systemd_dounit ${PN}.service
+
+	dodoc *.pdf
+}
-- 
cgit v1.2.3