From 21435953e16cda318a82334ddbadb3b5c36d9ea7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 15 Jan 2020 15:51:32 +0000
Subject: gentoo resync : 15.01.2020

---
 app-admin/mcelog/mcelog-168.ebuild | 58 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 app-admin/mcelog/mcelog-168.ebuild

(limited to 'app-admin/mcelog/mcelog-168.ebuild')

diff --git a/app-admin/mcelog/mcelog-168.ebuild b/app-admin/mcelog/mcelog-168.ebuild
new file mode 100644
index 000000000000..e0b67a2d755e
--- /dev/null
+++ b/app-admin/mcelog/mcelog-168.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit linux-info systemd toolchain-funcs
+
+DESCRIPTION="A tool to log and decode Machine Check Exceptions"
+HOMEPAGE="http://mcelog.org/"
+SRC_URI="https://github.com/andikleen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-mcelog )"
+
+# TODO: add mce-inject to the tree to support test phase
+RESTRICT="test"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		local CONFIG_CHECK="~X86_MCE"
+		kernel_is -ge 4 12 && CONFIG_CHECK+=" ~X86_MCELOG_LEGACY"
+		check_extra_config
+	fi
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.8_pre1-timestamp-${PN}.patch \
+		"${FILESDIR}"/${PN}-129-debugflags.patch
+	eapply_user
+	tc-export CC
+}
+
+src_install() {
+	default
+
+	insinto /etc/cron.daily
+	newins ${PN}.cron ${PN}
+
+	insinto /etc/logrotate.d/
+	newins ${PN}.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}.init-r1 ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	dodoc *.pdf
+}
+
+pkg_postinst() {
+	einfo "The default configuration set is now installed in /etc/${PN}"
+	einfo "you might want to edit those files."
+	einfo
+	einfo "A sample cronjob is installed into /etc/cron.daily"
+	einfo "without executable bit (system service is the preferred method now)"
+}
-- 
cgit v1.2.3