From 83ebb477861172671f6796999e016400b659d65f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 25 Feb 2023 15:53:45 +0000
Subject: gentoo auto-resync : 25:02:2023 - 15:53:45

---
 app-admin/clustershell/clustershell-1.9.1.ebuild | 57 ++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 app-admin/clustershell/clustershell-1.9.1.ebuild

(limited to 'app-admin/clustershell/clustershell-1.9.1.ebuild')

diff --git a/app-admin/clustershell/clustershell-1.9.1.ebuild b/app-admin/clustershell/clustershell-1.9.1.ebuild
new file mode 100644
index 000000000000..a630103853a9
--- /dev/null
+++ b/app-admin/clustershell/clustershell-1.9.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python framework for efficient cluster administration"
+HOMEPAGE="https://github.com/cea-hpc/clustershell/"
+SRC_URI="
+	https://github.com/cea-hpc/clustershell/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		app-shells/pdsh
+		net-misc/openssh
+		sys-devel/bc
+	)
+"
+
+RDEPEND="dev-python/pyyaml[${PYTHON_USEDEP}]"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	default
+
+	# remove test sets that require working ssh connection
+	rm tests/{CLIClush,TaskDistant*}Test.py || die
+}
+
+python_test() {
+	cd tests || die
+	# Automatic discovery does not work
+	"${EPYTHON}" -m unittest_or_fail -v *.py || die "Tests failed with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	einfo "Some default system-wide config files have been installed into"
+	einfo "/etc/${PN}"
+}
-- 
cgit v1.2.3