From b0378783c1929d283116fe183089c123dba5869c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 2 Oct 2022 13:12:50 +0100
Subject: gentoo auto-resync : 02:10:2022 - 13:12:50

---
 app-accessibility/orca/orca-43.0.ebuild | 62 +++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 app-accessibility/orca/orca-43.0.ebuild

(limited to 'app-accessibility/orca/orca-43.0.ebuild')

diff --git a/app-accessibility/orca/orca-43.0.ebuild b/app-accessibility/orca/orca-43.0.ebuild
new file mode 100644
index 000000000000..cedc398c4eb9
--- /dev/null
+++ b/app-accessibility/orca/orca-43.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-atk-2.34:2
+	>=app-accessibility/at-spi2-core-2.36:2[introspection]
+	>=dev-libs/atk-2.36
+	>=dev-libs/glib-2.28:2
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.18:3[${PYTHON_USEDEP}]
+	')
+	braille? (
+		$(python_gen_cond_dep '
+			>=app-accessibility/brltty-5.0-r3[python,${PYTHON_USEDEP}]
+			dev-libs/liblouis[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	dev-libs/atk[introspection]
+	$(python_gen_cond_dep '
+		>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+		>=dev-python/pyatspi-2.36[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+	')
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+BDEPEND="
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with braille liblouis)
+}
+
+src_install() {
+	gnome2_src_install
+	python_optimize
+}
-- 
cgit v1.2.3