From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 .../at-spi2-core/at-spi2-core-2.24.1.ebuild        | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 app-accessibility/at-spi2-core/at-spi2-core-2.24.1.ebuild

(limited to 'app-accessibility/at-spi2-core/at-spi2-core-2.24.1.ebuild')

diff --git a/app-accessibility/at-spi2-core/at-spi2-core-2.24.1.ebuild b/app-accessibility/at-spi2-core/at-spi2-core-2.24.1.ebuild
new file mode 100644
index 000000000000..20ebd6465e40
--- /dev/null
+++ b/app-accessibility/at-spi2-core/at-spi2-core-2.24.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2 multilib-minimal
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+LICENSE="LGPL-2+"
+SLOT="2"
+IUSE="X +introspection"
+KEYWORDS="alpha amd64 arm ~arm64 ~hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos"
+
+# x11-libs/libSM is needed until upstream #719808 is solved either
+# making the dep unneeded or fixing their configure
+# Only libX11 is optional right now
+RDEPEND="
+	>=dev-libs/glib-2.36:2[${MULTILIB_USEDEP}]
+	>=sys-apps/dbus-1[${MULTILIB_USEDEP}]
+	x11-libs/libSM[${MULTILIB_USEDEP}]
+	x11-libs/libXi[${MULTILIB_USEDEP}]
+	x11-libs/libXtst[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+		x11-libs/libXtst[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+PATCHES=(
+	# disable teamspaces test since that requires Novell.ICEDesktop.Daemon
+	"${FILESDIR}/${PN}-2.0.2-disable-teamspaces-test.patch"
+)
+
+multilib_src_configure() {
+	# xevie is deprecated/broken since xorg-1.6/1.7
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-xevie \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable X x11)
+
+	# work-around gtk-doc out-of-source brokedness
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/libatspi/html doc/libatspi/html || die
+	fi
+}
+
+multilib_src_compile() { gnome2_src_compile; }
+multilib_src_install() { gnome2_src_install; }
-- 
cgit v1.2.3