gentoo resync : 19.03.2019

1 files changed, 50 insertions, 0 deletions

diff --git a/sci-mathematics/genius/genius-1.0.23.ebuild b/sci-mathematics/genius/genius-1.0.23.ebuild
new file mode 100644
index 000000000000..aadd433bff97
--- /dev/null
+++ b/sci-mathematics/genius/genius-1.0.23.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="Genius Mathematics Tool and the GEL Language"
+HOMEPAGE="https://www.jirka.org/genius.html"
+SRC_URI="${SRC_URI}
+	doc? ( https://www.jirka.org/${PN}-reference.pdf )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc gnome"
+
+RDEPEND="
+	>=dev-libs/glib-2.16:2
+	dev-libs/gmp:0=
+	dev-libs/mpfr:0=
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	gnome? (
+		>=x11-libs/gtk+-2.18:2
+		x11-libs/gtksourceview:2.0
+		>=x11-libs/vte-0.26.0:0 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-update-icon-cache
+	dev-util/intltool
+	virtual/yacc
+	sys-devel/flex
+" # eautoreconf needs autoconf-archive
+# dev-util/gtk-update-icon-cache because configure checks for it for some reason and never calls it with DESTDIR set..
+
+src_configure() {
+	# Unrecognized --disable-scrollkeeper warning comes from gnome2.eclass adding it based on grep, but upstream has them commented out in .ac with "#" instead of "dnl"
+	gnome2_src_configure \
+		$(use_enable gnome) \
+		--enable-nls \
+		--disable-extra-gcc-optimization \
+		--disable-static
+}
+
+src_install() {
+	use doc && DOCS+=" ${DISTDIR}/${PN}-reference.pdf"
+	gnome2_src_install
+}