reinit the tree, so we can have metadata

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/dulwich/dulwich-0.9.9.ebuild b/dev-python/dulwich/dulwich-0.9.9.ebuild
new file mode 100644
index 000000000000..6aa147ef4093
--- /dev/null
+++ b/dev-python/dulwich/dulwich-0.9.9.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python implementation of the Git file formats and protocols"
+HOMEPAGE="https://github.com/jelmer/dulwich/ https://pypi.python.org/pypi/dulwich"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/gevent[$(python_gen_usedep python2_7)] )"
+RDEPEND=""
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# https://github.com/jelmer/dulwich/issues/196
+	if [[ "${EPYTHON}" == pypy ]]; then
+		"${PYTHON}" -m unittest dulwich.tests.test_suite || die "Tests failed under pypy"
+	else
+		emake check
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}